Skip to content
lsl.devlsl.devLSL Dev

llAddToLandPassList

View as MarkdownThis page as plain textOpen in ChatGPTAsk questions about this pageOpen in ClaudeAsk questions about this page
function
Function syntax
llAddToLandPassList(
  1. key avatar,// UUID of the avatar to add to the pass list.
  2. float hours// Duration, in hours, to allow the avatar for (range [0.0, 144.0], 0 for indefinite).
);
Delay
0.1 s
Energy
10

Adds the avatar to the land pass list for the specified number of hours (or indefinitely if hours is 0).

Add avatar to the land pass list for hours, or indefinitely if hours is zero.

How to use
llAddToLandPassList(NULL_KEY, 0.0);

Caveats

Section titled “Caveats”
  • The maximum usable value for hours is 144. Any value greater than 144 will be silently reduced to 144.

Examples

Section titled “Examples”
Example 1
76 collapsed lines
// This is not a complete solution, requires full avatar names to work - even for unbanning someone!
// This is meant only as an example of the land ban and pass management functions.
// free to copy, use, modify, distribute - just don't ask me to debug your modified code. ;-)
//
// Commands are:
//   /5 ban:full_avatar_name
//   /5 tempban:full_avatar_name
//   /5 unban:full_avatar_name
//   /5 pass:full_avatar_name
//   /5 unpass:full_avatar_name
//   /5 clearban
//   /5 clearpass


string command;


default
{
    state_entry()
    {
        llListen(5, "", llGetOwner(), "");
    }


    on_rez(integer param)
    {
        llResetScript();
    }


    listen(integer chan, string name, key id, string message)
    {
        if (command != "")
        {
            llOwnerSay("Sorry, still processing last command, try again in a second.");
        }


        list args = llParseString2List(message,[":"],[]);
        command = llToLower(llList2String(args,0));


        if (command == "clearbans")
        {
            llResetLandBanList();
        }
        if (command == "clearpass")
        {
            llResetLandPassList();
        }
        else
        {
            llSensor(llList2String(args,1),NULL_KEY,AGENT,96,PI);
        }
    }


    no_sensor()
    {
        command = "";
    }


    sensor(integer num)
    {
        integer i;
        for (i=0; i< num; ++i)
        {
            if (command == "ban")
            {
                // Ban indefinetely
                llAddToLandBanList(llDetectedKey(i),0.0);
            }
            if (command == "tempban")
            {
                // Ban for 1 hour.
                llAddToLandBanList(llDetectedKey(i),1.0);
            }
            if (command == "unban")
            {
                llRemoveFromLandBanList(llDetectedKey(i));
            }
            if (command == "pass")
            {
                // Add to land pass list for 1 hour
                llAddToLandPassList(llDetectedKey(i),1.0);
            }
            if (command == "unpass")
7 collapsed lines
            {
                llRemoveFromLandPassList(llDetectedKey(i));
            }
        }
        command = "";
    }
}

See also

Section titled “See also”

Functions

Section titled “Functions”
Original wiki source

Some wiki templates and tables need their original context. View this article on the Second Life Wiki. Technical wording and examples are retained from the source; historical guidance may differ from current behavior.