Skip to content
lsl.devlsl.devLSL Dev

llGetWallclock

View as MarkdownThis page as plain textOpen in ChatGPTAsk questions about this pageOpen in ClaudeAsk questions about this page
function
Function syntax
float llGetWallclock();
Returns
float
Energy
10

For GMT use llGetGMTclock

Returns a float that is the time in seconds since midnight Pacific time (PST/PDT), truncated to whole seconds. That is the same as the time of day in SLT expressed as seconds.

How to use
float result = llGetWallclock();

Examples

Section titled “Examples”
Example 1
11 collapsed lines
// Real World Sun
integer Flag;


default
{
    state_entry()
    {
        Flag = -1;
        llSetTimerEvent(0.1);
    }


    timer()
    {
        float time = llGetWallclock();
        if (Flag == -1)
        {
25 collapsed lines
            llSetTimerEvent(60.0);
        }
        if (time < 21600)
        {
            if (Flag)
            {
                llSetText("The Sun is coming! :)", <1,1,0>, 1.0);
                Flag = 0;
            }
        }
        else if (time < 64800)
        {
            if (Flag != 1)
            {
                llSetText("Sun has risen. :(", <1,0,0>, 1.0);
                Flag = 1;
            }
        }
        else if (Flag != 2)
        {
            llSetText("Goodbye Sun. :(", <1,0,0>, 1.0);
            Flag = 2;
        }
    }
}
Example 2
// Convert to human-readable HH:MM:SS format
string ConvertWallclockToTime()
{
    integer now = (integer)llGetWallclock();
    integer seconds = now % 60;
    integer minutes = (now / 60) % 60;
13 collapsed lines
    integer hours = now / 3600;
    return llGetSubString("0" + (string)hours, -2, -1) + ":"
        + llGetSubString("0" + (string)minutes, -2, -1) + ":"
        + llGetSubString("0" + (string)seconds, -2, -1);
}


default
{
    touch_start(integer total_number)
    {
        llSay(0, ConvertWallclockToTime());
    }
}
Example 3
// Convert to human-readable 12-hour HH:MM:SS (AM/PM) format
string ConvertWallclockToTime()
{
    integer now = (integer)llGetWallclock();
    integer seconds = now % 60;
    integer minutes = (now / 60) % 60;
15 collapsed lines
    integer hours = now / 3600;


    return llGetSubString("0" + (string)(hours % 12), -2, -1) + ":"
           + llGetSubString("0" + (string)minutes, -2, -1) + ":"
           + llGetSubString("0" + (string)seconds, -2, -1) + " "
           + llList2String(["AM", "PM"], (hours > hours % 12));
}


default
{
    touch_start(integer total_number)
    {
        llSay(0, ConvertWallclockToTime());
    }
}

Notes

Section titled “Notes”

To determine if the current time returned by this function is PST or PDT, you can look at the difference between llGetGMTclock() and llGetWallclock(). The difference will be either 8 hours or -16 hours for PST, and 7 hours or -17 hours for PDT, that is 28800 or -57600, or 25200 or -61200 seconds.

See also

Section titled “See also”

Functions

Section titled “Functions”
Original wiki source

Some wiki templates and tables need their original context. View this article on the Second Life Wiki. Technical wording and examples are retained from the source; historical guidance may differ from current behavior.

From the Second Life Wiki

Community documentation adapted from LlGetWallclock, by Linden Research, Inc. and contributing residents.View contributors and history.

Imported wiki revision:

Licensed under CC BY-SA 3.0. Last wiki edit: .Formatting and links have been adapted for this site; API metadata follows the LSL definitions.