Skip to content
lsl.devlsl.devLSL Dev

llListFindList

View as MarkdownThis page as plain textOpen in ChatGPTAsk questions about this pageOpen in ClaudeAsk questions about this page
function
Function syntax
integer llListFindList(
  1. list src,// List to search within.
  2. list test// List elements to search for.
);
Returns
integer
Energy
10

If test is not found in src, -1 (in LSL) or nil (in SLua) is returned.

The index of the first entry in the list is 0

If test is found at the last index in src the positive index is returned (5th entry of 5 returns 4).

How to use
integer result = llListFindList([], []);

Caveats

Section titled “Caveats”
  • Strict type matching and case sensitivity is enforced.
  • “1” != 1
  • “1.0” != 1.0
  • 1 != 1.0
  • “a822ff2b-ff02-461d-b45d-dcd10a2de0c2” != (key)“a822ff2b-ff02-461d-b45d-dcd10a2de0c2”
  • “Justice” != “justice”
  • If test is an empty list the value returned is 0 rather than -1.

Examples

Section titled “Examples”
Example 1
list numbers = [1, 2, 3, 4, 5];
default
{
    state_entry()
    {
        integer index = llListFindList(numbers, [3]);
        if (index != -1)
        {
            list three_four = llList2List(numbers, index, index + 1);
            llOwnerSay(llDumpList2String(three_four, ","));
            // Object: 3,4
        }
    }
}
Example 2
//You can also search for two items at once to find a pattern in a list
list avatarsWhoFoundMagicLeaves = ["Fire Centaur","Red Leaf"];
default
{
    state_entry()
    {
        integer index = llListFindList(avatarsWhoFoundMagicLeaves, ["Fire Centaur","Red Leaf"]);
        if (index != -1)
        {
            list output = llList2List(avatarsWhoFoundMagicLeaves, index, index + 1);
            llOwnerSay(llDumpList2String(output, ","));
            // Object: Fire Centaur, Red Leaf
        }
    }
}

Helper functions

Section titled “Helper functions”

An easy way to see if an item exists in a list…

if(~llListFindList(myList, (list)item))
{//it exists
    // This works because ~(-1) produces 0, but ~ of any other value produces non-zero and causes the 'if' to succeed
    // So any return value (including 0) that corresponds to a found item, will make the condition succeed
    // It saves bytecode and is faster then doing != -1
    // This is a bitwise NOT (~) not a negation (-)
}

Known issues

Section titled “Known issues”

From the issue templates included by the wiki article:

  • SVC-5146 (nf): llSortedListFindList() - improved llListFindList() for known to be sorted lists
  • BUG-10924 (nf): llSubListFindList() - Search within a sub-list

See also

Section titled “See also”

Functions

Section titled “Functions”
Original wiki source

Some wiki templates and tables need their original context. View this article on the Second Life Wiki. Technical wording and examples are retained from the source; historical guidance may differ from current behavior.