Skip to content
lsl.devlsl.devLSL Dev

llUnSit

View as MarkdownThis page as plain textOpen in ChatGPTAsk questions about this pageOpen in ClaudeAsk questions about this page
function
Function syntax
llUnSit(
  1. key id// UUID of the avatar to unsit.
);
Energy
10

The agent identified by id is forced to stand up if any of the following apply:

  • The agent is sitting on the scripted object
  • The agent is over land owned by the scripted object’s owner and/or a group the owner has land rights for.
How to use
llUnSit(NULL_KEY);

Examples

Section titled “Examples”
Example 1
11 collapsed lines
// UnSit on Sit, Using a sit target
default
{
    state_entry()
    {
        llSitTarget(<0.0, 0.0, 0.1>, ZERO_ROTATION); // Needed for llAvatarOnSitTarget to work. The vectors components must not all be set to 0.0
    }
    changed(integer change) // Triggered when various changes are sensed.
    {
        if(change & CHANGED_LINK) // When an agent sits on an object they become a new link.
        {
            key user = llAvatarOnSitTarget(); // Store the UUID of any agent sitting on the sit target.
            if(user) // An avatar is on the sit target.
                llUnSit(user); // Un-Sit the avatar.
        }
    }
}
Example 2
9 collapsed lines
// UnSit on Sit, NOT using a sit target


default
{
    changed(integer change) // Triggered when various changes are sensed.
    {
        if(change & CHANGED_LINK) // When an agent sits on an object they become a new link.
        {
            integer links = 0; // Create an integer type variable.
            if(llGetObjectPrimCount(llGetKey()) < (links = llGetNumberOfPrims())) // During the check store the number of links.
            // If the number of prims is fewer than the number of links, the last must be an avatar.
                llUnSit(llGetLinkKey(links)); // Use the key of the last link to be added (the avatar) to call llUnSit().
            else
                llOwnerSay("Some kind of linking or unlinking has changed me but, I am not being sat on.");
            // llUnSit() triggers the changed event too (the number of links is reduced by 1).
        }
    }
}
Example 3
unsit_all_avatars()
{
    integer objectPrimCount = llGetObjectPrimCount(llGetKey());
    integer currentLinkNumber = llGetNumberOfPrims();


    for (; objectPrimCount < currentLinkNumber; --currentLinkNumber)
        llUnSit(llGetLinkKey(currentLinkNumber));
}


7 collapsed lines
default
{
    touch_start(integer num_detected)
    {
        unsit_all_avatars();
    }
}

Known issues

Section titled “Known issues”

From the issue templates included by the wiki article:

  • SVC-924 (nf): llSit() - scriptable ability to force an avatar to sit on an object

See also

Section titled “See also”

Functions

Section titled “Functions”

Events

Section titled “Events”
Original wiki source

Some wiki templates and tables need their original context. View this article on the Second Life Wiki. Technical wording and examples are retained from the source; historical guidance may differ from current behavior.