Skip to content
lsl.devlsl.devLSL Dev

llGetAgentSize

View as MarkdownThis page as plain textOpen in ChatGPTAsk questions about this pageOpen in ClaudeAsk questions about this page
function
Function syntax
vector llGetAgentSize(
  1. key avatar// UUID of the avatar in the same region.
);
Returns
vector
Energy
10

ZERO_VECTOR is returned if avatar is not in the region or if it is not an avatar.

Returns a vector that is an estimated size of the requested avatar.

How to use
vector result = llGetAgentSize(NULL_KEY);

Caveats

Section titled “Caveats”
  • The returned vector is an estimate calculated from the avatar’s current shape including shoes. x is a constant 0.45, y is a constant 0.60, z is the approximate total height of all avatar’s bones, with an arbitrary amount added or subtracted based on the current shape’s “Hover” setting. Reported height is constrained to the range 1.1 to 2.45 meters, and does not include animation or mesh bone offsets. 1
    • Due to the shape Hover setting, and mesh and animation offsets, it is not possible to use this function to determine the rendered height of an avatar with any degree of confidence.
  • As of Second Life Server 13.11.19.284082, the return value is the avatar’s reported bounding box - <0.1, 0.1, 0.2> when standing. (Avatar bounding boxes have historically been redefined with major physics upgrades.) An avatar’s bounding box changes when an avatar sits, while llGetAgentSize is constant for as long as the shape does not change.

Examples

Section titled “Examples”
Example 1
5 collapsed lines
//A simple script that makes a box hover above the owner's head.
default
{
    state_entry()
    {
        key    owner = llGetOwner();
        vector pos   = llList2Vector(llGetObjectDetails(owner, [OBJECT_POS]), 0);
        vector agent = llGetAgentSize(owner);


    //  "pos" needs to be adjusted so it appears above the owner.
12 collapsed lines
        pos.z += 0.5 + agent.z / 2;


    //  makes sure it found the owner, a zero vector evaluates as false
        if(agent)
            llSetPos(pos);
    }


    touch_start(integer num)
    {
        llResetScript();
    }
}

Notes

Section titled “Notes”
  • This function is a good way to quickly test…
    • if an avatar is in the same region.
    • if a UUID known to be in the region is an avatar.

To use this function to test either case use as follows

if(llGetAgentSize(uuid)) {
    //uuid is an avatar in the region
} else {
    //uuid is not an avatar in the region
}
  • DEFAULT_AGENT_HEIGHT in is 1.9. This will be the z value if an avatar’s shape has not loaded yet. It is possible but extremely rare to see a fully loaded avatar with this exact size, so:
vector agentSize = llGetAgentSize(uuid);
if (agentSize.z == 1.9) {
    // avatar is probably Ruthed
}

See also

Section titled “See also”

Functions

Section titled “Functions”

Articles

Section titled “Articles”
Original wiki source

Some wiki templates and tables need their original context. View this article on the Second Life Wiki. Technical wording and examples are retained from the source; historical guidance may differ from current behavior.

Footnotes

Section titled “Footnotes”

  1. llGetAgentSize returns the same value as . See for defaults and limits. ↩