llGetListLength

Category: List

function

Function syntax

integer llGetListLength(

list src// List to measure.

);

Returns: integer
Energy: 10

Returns an integer representing the total number of elements in the list src.

Returns an integer that is the number of elements in the list src.

integer result = llGetListLength([]);

Examples

Example 1

//Basic usage
default
{
    state_entry()
    {
        list testList = ["one", "two", "three"];
        integer length = llGetListLength(testList);
        llOwnerSay("There are " + (string)length + " entries in the list.");
    }
}

Notes

Best Practices

When using list length to help you loop through a list, it is better to determine the length first, then start your loop:

integer length = llGetListLength(mylist);

integer index;// default is 0
while (index < length)
{
    llSay(0, llList2String(mylist, index));
    ++index;
}

The following example is to illustrate what not to do, it calculates the length in the “for” loop and is inefficient because the length gets recalculated at each pass through the loop. This should only ever be done if the list is in fact changing (in length) with each iteration of the loop¹.

integer index;// default is 0
while (index < llGetListLength(mylist))
{
    llSay(0, llList2String(mylist, index));
    ++index;
}

LSO Optimizations

A faster and lighter (in bytecode) way to determine the length of a list is to do a not-equals compare with a null list. This works because the list not-equals compare returns the difference between the lengths, meaning that it returns the same result as llGetListLength(), minus the overhead in bytecode, and performance penalty of calling a non-native function. Note: This optimization is much less beneficial time-wise in Mono as Mono’s llGetListLength function is almost twice as fast, however the bytecode saving is still about 30 bytes.

list in;
integer len_in = llGetListLength(in);
integer flen_in = (in != []);
//flen_in and len_in will be the same

integer neg_len_in = -llGetListLength(in);
integer fneg_len_in = ([] != in);
//fneg_len_in and neg_len_in will be the same

Known issues

SVC-6364: Automatically optimise calls to llGetListLength(list) by replacing them with (list != [])

llGetListLength

Examples

Notes

Best Practices

LSO Optimizations

Known issues

See also

Functions

llGetListLength

Examples

Notes

Best Practices

LSO Optimizations

Known issues

See also

Functions

Footnotes