Skip to content
lsl.devlsl.devLSL Dev

llReleaseURL

View as MarkdownThis page as plain textOpen in ChatGPTAsk questions about this pageOpen in ClaudeAsk questions about this page
function
Function syntax
llReleaseURL(
  1. string url// URL string to release.
);
Energy
10

Releases the specified url (previously obtained via llRequestURL), rendering it no longer usable.

Releases the specified URL, it will no longer be usable.

How to use
llReleaseURL("");

Caveats

Section titled “Caveats”
  • URLs are automatically released and invalidated in certain situations. In the following situations, there is no need to call llReleaseURL. But you will have to request a new one afterwards
  • When the region is restarted or goes offline
  • When the script holding the URLs is reset, or recompiled
  • When the object containing the script is deleted, or taken to inventory

Examples

Section titled “Examples”
Example 1
string url;
key urlRequestId;
key selfCheckRequestId;


request_url()
{
    llReleaseURL(url);
    url = "";
    llSetTimerEvent(0.0);
82 collapsed lines
    urlRequestId = llRequestURL();
}


throw_exception(string inputString)
{
    llInstantMessage(llGetOwner(), inputString);


    // yeah, bad way to handle exceptions by restarting.
    // However this is just a demo script...


    llResetScript();
}


default
{
    on_rez(integer start_param)
    {
        llResetScript();
    }


    changed(integer change)
    {
        if (change & CHANGED_OWNER | CHANGED_REGION | CHANGED_REGION_START)
            llResetScript();
    }


    state_entry()
    {
        request_url();
    }


    http_request(key id, string method, string body)
    {
        integer responseStatus = 400;
        string responseBody = "Unsupported method";


        if (method == URL_REQUEST_DENIED)
            throw_exception("The following error occurred while attempting to get a free URL for this device:\n \n" + body);
        else if (method == URL_REQUEST_GRANTED)
        {
            url = body;
            llLoadURL(llGetOwner(), "Click to visit my URL!", url);


            // check every 5 mins for dropped URL
            llSetTimerEvent(300.0);
        }
        else if (method == "GET")
        {
            responseStatus = 200;
            responseBody = "Hello world!";
        }
        // else if (method == "POST") ...;
        // else if (method == "PUT") ...;
        // else if (method == "DELETE") { responseStatus = 403; responseBody = "forbidden"; }


        llHTTPResponse(id, responseStatus, responseBody);
    }


    http_response(key id, integer status, list metaData, string body)
    {
        if (id == selfCheckRequestId)
        {
            // If you're not usually doing this,
            // now is a good time to get used to doing it!
            selfCheckRequestId = NULL_KEY;


            if (status != 200)
                request_url();
        }
        else if (id == NULL_KEY)
            throw_exception("Too many HTTP requests too fast!");
    }


    timer()
    {
        selfCheckRequestId = llHTTPRequest(url,
                                [HTTP_METHOD, "GET",
                                    HTTP_VERBOSE_THROTTLE, FALSE,
                                    HTTP_BODY_MAXLENGTH, 16384],
                                "");
    }
}

History

Section titled “History”
  • SVN:1836 r112899 Trunk

See also

Section titled “See also”

Functions

Section titled “Functions”

Articles

Section titled “Articles”
Original wiki source

Some wiki templates and tables need their original context. View this article on the Second Life Wiki. Technical wording and examples are retained from the source; historical guidance may differ from current behavior.

From the Second Life Wiki

Community documentation adapted from LlReleaseURL, by Linden Research, Inc. and contributing residents.View contributors and history.

Imported wiki revision:

Licensed under CC BY-SA 3.0. Last wiki edit: .Formatting and links have been adapted for this site; API metadata follows the LSL definitions.