Skip to content
lsl.devlsl.devLSL Dev

llRequestSecureURL

View as MarkdownThis page as plain textOpen in ChatGPTAsk questions about this pageOpen in ClaudeAsk questions about this page
function
Function syntax
key llRequestSecureURL();
Returns
key
Energy
10

Requests one HTTPS:// (SSL) URL for use by this object. The http_request event is triggered with result of the request. HTTPS-in uses port 12043.

Returns a key used for identifying the result of the request in the http_request event.

How to use
key result = llRequestSecureURL();

Caveats

Section titled “Caveats”
  • HTTPS-in uses port 12043 (that port is in the URL returned by this method).
  • When a region is (re)started all HTTP server URLs are automatically released and invalidated.
  • Use CHANGED_REGION_START to detect this so a new URL can be requested.

Examples

Section titled “Examples”
Example 1

Requesting a secure URL:

7 collapsed lines
string secureUrl;
key urlRequestId;
key selfCheckRequestId;


request_secure_url()
{
    llReleaseURL(secureUrl);
    secureUrl = "";


    urlRequestId = llRequestSecureURL();
}


91 collapsed lines
throw_exception(string inputString)
{
    key owner = llGetOwner();
    llInstantMessage(owner, inputString);


    // yeah, bad way to handle exceptions by restarting.
    // However this is just a demo script...


    llResetScript();
}


default
{
    on_rez(integer start_param)
    {
        llResetScript();
    }


    changed(integer change)
    {
        if (change & (CHANGED_OWNER | CHANGED_INVENTORY))
        {
            llReleaseURL(secureUrl);
            secureUrl = "";


            llResetScript();
        }


        if (change & (CHANGED_REGION | CHANGED_REGION_START | CHANGED_TELEPORT))
            request_secure_url();
    }


    state_entry()
    {
        request_secure_url();
    }


    http_request(key id, string method, string body)
    {
        integer responseStatus = 400;
        string responseBody = "Unsupported method";


        if (method == URL_REQUEST_DENIED)
            throw_exception("The following error occurred while attempting to get a free URL for this device:\n \n" + body);


        else if (method == URL_REQUEST_GRANTED)
        {
            secureUrl = body;
            key owner = llGetOwner();
            llLoadURL(owner, "Click to visit my URL!", secureUrl);


            // check every 5 mins for dropped URL
            llSetTimerEvent(300.0);
        }
        else if (method == "GET")
        {
            responseStatus = 200;
            responseBody = "Hello world!";
        }
        // else if (method == "POST") ...;
        // else if (method == "PUT") ...;
        // else if (method == "DELETE") { responseStatus = 403; responseBody = "forbidden"; }


        llHTTPResponse(id, responseStatus, responseBody);
    }


    http_response(key id, integer status, list metaData, string body)
    {
        if (id == selfCheckRequestId)
        {
            // If you're not usually doing this,
            // now is a good time to get used to doing it!
            selfCheckRequestId = NULL_KEY;


            if (status != 200)
                request_secure_url();
        }


        else if (id == NULL_KEY)
            throw_exception("Too many HTTP requests too fast!");
    }


    timer()
    {
        selfCheckRequestId = llHTTPRequest(secureUrl,
                                [HTTP_METHOD, "GET",
                                    HTTP_VERBOSE_THROTTLE, FALSE,
                                    HTTP_BODY_MAXLENGTH, 16384],
                                "");
    }
}

History

Section titled “History”
  • SVN:1836 r112899 Trunk

See also

Section titled “See also”

Functions

Section titled “Functions”

Articles

Section titled “Articles”
Original wiki source

Some wiki templates and tables need their original context. View this article on the Second Life Wiki. Technical wording and examples are retained from the source; historical guidance may differ from current behavior.

From the Second Life Wiki

Community documentation adapted from LlRequestSecureURL, by Linden Research, Inc. and contributing residents.View contributors and history.

Imported wiki revision:

Licensed under CC BY-SA 3.0. Last wiki edit: .Formatting and links have been adapted for this site; API metadata follows the LSL definitions.