llOwnerSay

function

Function syntax

llOwnerSay(

string msg// Text message string to send to the object owner.

);

Energy: 10

Sends the chat message msg privately to the object owner (the owner must be currently in the same region for the message to be received).

Says msg to the object’s owner only, if the owner is currently in the same region.

llOwnerSay("");

Caveats

If msg is longer than 1024 bytes, it will be truncated to 1024 bytes. This can convey 1024 ASCII characters, or fewer if non-ASCII are present.
Silently fails ~45 seconds after the owner leaves the region the object is in.
Silently fails when the object to which the script is attached is deeded to a group.
Some viewers do not display llOwnerSay text when msg is empty ("").
Produces swirly particle effects for the owner (who sees the message) but these effects do not appear to be visible to other avatars (who don’t).

Examples

Example 1

default
{
    touch_start(integer num_detected)
    {
        llOwnerSay("Ouch!");
    }
}

Helper functions

// llOwnerSay extension for preventing silent failures
// paste this code at the top of the script and replace
// any calls to llOwnerSay with uOwnerSayPlus

uOwnerSayPlus(string inputString)
{
    key owner = llGetOwner();

    // single owner that the region still has a handle for
    if (llKey2Name(owner))
    {
        llOwnerSay(inputString);
    }
    // group owned, must send the message publicly
10 collapsed lines
    else if (llList2Key(llGetObjectDetails(llGetKey(), [OBJECT_GROUP]), 0) == owner)
    {
        llWhisper(0, "/me : " + inputString);
    }
    // single owner, not present, send them an IM
    else
    {
        llInstantMessage(owner, inputString);
    }
}

Tests

llOwnerSay Test