LlSetPayPrice

Wiki description

Suggest default amounts for the pay text field and pay buttons of the appearing dialog when someone chooses to pay this object.

Specification

Constant		Alt	Description
PAY_HIDE	-1	0	Hides this quick pay button.
PAY_DEFAULT	-2		Use the default value for this quick pay button.

Button Order
1	2
3	4

Defaults
$1	$5
$10	$20

Caveats

This function should not be trusted to limit the values of money payable to the object; always verify the amount paid is the amount expected.
Use only one call to this function in all the scripts on an object to prevent confusion about which values are used. You still need to check in the money event that the amount is as expected.
This function only works when called from the root prim of an object. Its effect applies to all the prims in the object. Calling it from a child prim has no effect.
- There is currently a viewer bug where calls from child prims will prevent payment to the object.
Payment to a prim can be blocked by the llSetPayPrice() setting in the prim, which persists even if the script with llSetPayPrice() is removed.
Caution: Calling this function will enable payment on the prim (or the whole object if it is the root prim) for the current state, even when this state has no money event.
Otherwise, the pay option will only be shown in prims having a running script with a money event (or in all the prims of the object if the root has a running script with a money event).
The effect seems to persist even if the script is recompiled with out the llSetPayPrice function, even if the script is replaced with another one which includes a money event, but not llSetPayPrice.
Money cannot be paid to an attachment; "Pay" will go directly to the wearer instead.
If quick_pay_buttons contains a negative value or zero, the button will not be shown at all.
- However, zero is allowed for price, which is used to set the custom text field's value within the Pay window.
If price is PAY_HIDE and a payment is made that does not match any value in quick_pay_buttons, then the simulator will block the payment and the payer will receive an error message.

Examples

This will give the user a dialog box without the price field and only one button with a value of 150.

llSetPayPrice(PAY_HIDE, [150,PAY_HIDE,PAY_HIDE,PAY_HIDE])

integer price = 10;

default
{
    state_entry()
    {
        llSetPayPrice(PAY_HIDE, [PAY_HIDE ,PAY_HIDE, PAY_HIDE, PAY_HIDE]);
        llRequestPermissions(llGetOwner(), PERMISSION_DEBIT);
    }
    run_time_permissions(integer perm)
    {
        if(perm & PERMISSION_DEBIT)
            state cash;
    }
}

state cash
{
    state_entry()
    {
        llSetPayPrice(price, [price ,PAY_HIDE, PAY_HIDE, PAY_HIDE]);
    }
    money(key id, integer amount)
    {
        if(amount != price)
        {
            llGiveMoney(id, amount);
            llInstantMessage(id, "You paid "+(string)amount+", which is the wrong price, the price is: "+(string)price);
        }
        else
        {
            //insert your give code here.
            llInstantMessage(id, "You paid the right price");
        }
    }
}

Tests

Shared wiki helpers

The original page also injects shared parameter notes, caveats or issue information through these helpers. Their conditional MediaWiki logic is not reproduced here; inspect the preserved helper source for additional material.

Template:Issues/VWR-3048

Original shared helper source (conditional wiki logic is not evaluated)

{{Issues|VWR-3048|type=bug|[[llSetPayPrice]] doesn't work on Child Prims, default box used instead.}}

Template:Issues/VWR-8744