Skip to content
lsl.devlsl.devLSL Dev

PRIM_MATERIAL

View as MarkdownThis page as plain textOpen in ChatGPTAsk questions about this pageOpen in ClaudeAsk questions about this page
constant
Constant
integer PRIM_MATERIAL = 2;

Constant groups

PrimParam · PrimParamGet

Other PrimParam values (42)
Other PrimParamGet values (40)

Sets the prim material. Material does not affect mass, but does affect friction, bounce (elasticity), and collision sound. On a wood incline of 33 degrees, the example script below gave the following results:

Table detailing maximum velocity and distance traveled down the incline.

TypeVelocity (m/s)Distance (m)
Stone0.4531810.361655
Metal5.47544410.211180
Glass6.48315011.678304
Wood2.1545499.433724
Flesh0.3515430.188043
Plastic4.5024289.590952
Rubber0.3749640.187106

Examples

Section titled “Examples”
Example 1
56 collapsed lines
// © 2008 by Karzita Zabaleta
// Author of Scripting Your World, Wiley, October 2008.


list gMaterialTypes = [
  "STONE",
  "METAL",
  "GLASS",
  "WOOD",
  "FLESH",
  "PLASTIC",
  "RUBBER"
];


vector   gHomePosition;
rotation gHomeRotation;
integer  gWaitCount = 0;
float    gMaxVelMag;
integer  gPrimMaterial;


moveTo(vector origin, vector destination) {
    float dist = llVecDist(origin, destination);
    integer passes = llCeil( llLog(dist/10.0) / llLog(2.0) );
    integer i;
    list params = [PRIM_POSITION, destination];
    for (i=0; i<passes; i++) {
        params = (params=[]) + params + params;
    }
    // actually move the prim, now
    llSetPrimitiveParams(params);
}


returnHome()
{
    llSetStatus(STATUS_PHYSICS, FALSE);
    moveTo(llGetPos(),gHomePosition);
    llSetTimerEvent(0);
    llSetRot(gHomeRotation);
}


calculate_velocity()
{
    float velMag = llVecMag(llGetVel());
    if (velMag > gMaxVelMag) {
        gMaxVelMag = velMag;
    }
}


default
{
    state_entry() {
        gHomePosition = llGetPos();
        gHomeRotation = llGetRot();
    }
    on_rez(integer _n) {
        llResetScript();
    }
    touch_start(integer n) {
        gMaxVelMag = 0;
        llSetPrimitiveParams([PRIM_MATERIAL, gPrimMaterial]);
        llSetStatus(STATUS_PHYSICS,TRUE);
        llSetTimerEvent(0.1);
16 collapsed lines
        llResetTime();
        gWaitCount=0;
        gPrimMaterial++;
        if (gPrimMaterial == 7 ) gPrimMaterial = 0;
    }
    timer() {
        calculate_velocity();
        gWaitCount++;
        if (gWaitCount > 100) { // 10 seconds
            string type = llList2String( gMaterialTypes, gPrimMaterial-1 );
            llOwnerSay(type+" reached maximum velocity of "+(string)gMaxVelMag+
                       " and traveled "+(string)llVecDist(llGetPos(), gHomePosition)+" meters.");
            returnHome();
        }
    }
}

See also

Section titled “See also”

Constants

Section titled “Constants”

|

ConstantTypeValueDescription
PRIM_MATERIAL_STONEinteger0stone
PRIM_MATERIAL_METALinteger1metal
PRIM_MATERIAL_GLASSinteger2glass
PRIM_MATERIAL_WOODinteger3wood
PRIM_MATERIAL_FLESHinteger4flesh
PRIM_MATERIAL_PLASTICinteger5plastic
PRIM_MATERIAL_RUBBERinteger6rubber
PRIM_MATERIAL_LIGHTinteger7light, DEPRECATED: Looks the same as [ PRIM_FULLBRIGHT, ALL_SIDES, TRUE ]
material FlagsDescriptionFrictionRestitution
0.80.4
0.30.4
0.20.7
0.60.5
0.90.3
0.40.7
0.90.9
light, DEPRECATED: Looks the same as [ PRIM_FULLBRIGHT, ALL_SIDES, TRUE ]0.60.5

Functions

Section titled “Functions”

Events

Section titled “Events”
Original wiki source

Some wiki templates and tables need their original context. View this article on the Second Life Wiki. Technical wording and examples are retained from the source; historical guidance may differ from current behavior.