llGetTime

function

Function syntax

float llGetTime();

Returns: float
Energy: 10

Returns a float representing the elapsed script time in seconds with subsecond precision (since the script started, was reset, or since the last call to llResetTime or llGetAndResetTime).

Returns a float that is script time in seconds with subsecond precision since the script started, was last reset, or call to either llResetTime or llGetAndResetTime.

float result = llGetTime();

Specification

Script time matches normal time, it is unaffected by time dilation. For example, if you call llResetTime on two objects in separate simulators at the same time, and later call llGetTime on both at the same time, their values will be equal regardless of differences in dilation.

Caveats

Script time is the amount of real-world time that the script has been in a running state. It is unaffected by time dilation, but it does not count time while the script is suspended, the user is offline (when in an attachment), the object is in inventory rather than rezzed, etc.
Script time resets when…
Script reset (user or llResetScript or llResetOtherScript)
Call to either llResetTime or llGetAndResetTime
Due to (32 bit) floating point number limitations, the accuracy of this function is 1/₆₄sec up to ~3 days, 1/₃₂sec up to ~6 days, etc… doubling each time, e.g. it’s only 1 second at ~194 days. Use llResetTime or llGetAndResetTime whenever practical to maintain the accuracy you require:

Floating Point Precision Thesholds
Precision	Up to Seconds	Hours	Days
0.016=2^-6	262144=2¹⁸	72.82	3.03
0.022=¹/₄₅	1 simulator frame
0.031=2^-5	524288=2¹⁹	145.63	6.06
0.063=2^-4	1048576=2²⁰	291.27	12.13
0.125=2^-3	2097152=2²¹	582.54	24.27
0.250=2^-2	4194304=2²²	1165.08	48.54
0.500=2^-1	8388608=2²³	2330.16	97.09
1.000=2^-0	16777216=2²⁴	4660.33	194.18

Note that this precision caveat does not apply to scripts written in SLua, only to LSL scripts. In SLua:
the timer precision is 64-bit, and will maintain 1/₆₄sec precision for ~4.4million years.
llResetTime and llGetAndResetTime have been removed

Examples

Example 1

default {
    state_entry()
    {
        llResetTime();
    }
    touch_start(integer num_touch)
    {
        float time = llGetTime(); //Instead getting, and then resetting the time, we could use llGetAndResetTime() to accomplish the same thing.
        llResetTime();
        llSay(0,(string)time + " seconds have elapsed since the last touch." );
    }
}

Example 2

6 collapsed lines
// Distinguish between a single click and a double click

float gHoldTime;

default
{
    touch_start(integer total_number)
    {
        float now = llGetTime();
        if (now - gHoldTime < 0.3)
        {
11 collapsed lines
            llSay(PUBLIC_CHANNEL,"Double clicked");
            // Trigger one sequence of actions
        }
        else
        {
            llSetTimerEvent(0.32);
        }
        gHoldTime = now;
    }

    timer()
    {
        llSetTimerEvent(0.0);
        if (llGetTime()-gHoldTime > 0.3)
        {
            llSay(PUBLIC_CHANNEL,"Single clicked.");
            // Trigger a different sequence of actions
        }
    }
}

Example 3

//  To do time-dependant loops of whatever:
//  for example move 2 meters within 5.0 seconds

float time = 5.0;
float i;
llResetTime();
do
{
    i = llGetTime()/time;
    // move2meters*i
}
while (llGetTime() < time);

Known issues

SVC-3293: llGetTime doesn’t reset on admin requested sim restart